===== MAIN.prg =====

RESET/DISPLAY
CREATE/GRAPHICS
SET/CONTEXT SPEC
SET/GRAPH XAXIS=AUTO
SET/GRAPH YAXIS=AUTO
CREATE/ICATALOG temp1.cat NULL
CREATE/ICATALOG temp2.cat NULL
CREATE/ICATALOG temp3.cat NULL
CREATE/ICATALOG temp4.cat NULL           
CREATE/ICATALOG temp5.cat NULL 
WRITE/OUT DONT FORGET PARAMETERS!!!!!!!
ENTRY STOP

WRITE/OUT fits => bdf converting...
INTAPE/FITS 1-50 data data

CREATE/ICATALOG temp0.cat data*.bdf

WRITE/OUT removing spikes, use mouse.
EXECUTE/CATALOG MODIFY/GCURS temp0.cat

WRITE/OUT smoothing...
EXECUTE/CATALOG SUB0.prg temp1.cat temp0.cat 4    !Warning

WRITE/OUT calibrating spectras, use cursor...
SET/GRAPH XAXIS=6570,6580                         !Warning
SET/GRAPH YAXIS=0,5                               !Warning
plot xdata0001
CENTER/GAUSS GCURSOR slask ABSORPTION
WRITE/KEYWORD calval/r/1/1 0
COPY/TK slask :CENTER @1 calval
EXECUTE/CATALOG SUB1.prg temp2.cat temp1.cat calval

WRITE/OUT scale transformation...
WRITE/KEY peak/r/1/1 6562.8                          !Important
WRITE/KEY starvel/r/1/1 16.0                         !Important
EXECUTE/CATALOG SUB2.prg temp3.cat temp2.cat peak starvel

WRITE/OUT normalisation...
EXECUTE/CATALOG SUB3.prg temp4.cat temp3.cat

WRITE/OUT rebinning..
COPY/II data0001 slask
EXECUTE/CATALOG SUB4.prg temp5.cat temp4.cat -350 2 150  !Important

WRITE/OUT creating ascii files
EXECUTE/CATALOG SUB5.prg slask temp5.cat

SET/GRAPH XAXIS=AUTO
PLOT xxxxxdata0001
EXECUTE/CATALOG OVERPLOT temp5.cat
===== SUB0.prg =====
FILTER/MEDIAN 'P2' x'P2' 'P3'
WRITE/OUT x'P2' created

===== SUB1.prg =====
PLOT 'P2'
CENTER/GAUSS GCURSOR slask ABSORPTION
COPY/II 'P2' x'P2'
WRITE/KEY center/r/1/1 0.0
WRITE/KEY start/r/1/1 0.0
WRITE/KEY newstart/r/1/1 0.0
COPY/TK slask :CENTER @1 center
COPY/DK 'P2' START start
COMPUTE/KEY newstart = start - center + 'P3'
COPY/KD newstart x'P2' START
WRITE/OUT x'P2' created

===== SUB2.prg =====
WRITE/KEY step0/r/1/1 0.0
WRITE/KEY step1/r/1/1 0.0
WRITE/KEY start0/r/1/1 0.0
WRITE/KEY start1/r/1/1 0.0
COPY/DK 'P2' step step0
COPY/DK 'P2' start start0
COMPUTE/KEY step1 = step0 * 300000 / 'P3'
COMPUTE/KEY start1 = -(('P3'-start0) / step0 * step1) - 'P4' 
COPY/II 'P2' x'P2'
COPY/KD step1 x'P2' step
COPY/KD start1 x'P2' start
WRITE/OUT x'P2' created

===== SUB3.prg =====
FILTER/MEDIAN 'P2' slask.1 10.
NORM/SPEC slask.1 slask.2
COMP/IMA x'P2' = 'P2'/slask.2
WRITE/OUT x'P2' created

===== SUB4.prg =====
WRITE/DESCRIPTOR slask start/d/1/1 'P3'
WRITE/DESCRIPTOR slask step/d/1/1 'P4'
WRITE/KEY pix/d/1/1 0
COMPUTE/KEY pix = - 2 * ( 'P3' / 'P4' ) + 1 + ( 'P5' / 'P4')
REBIN/LINEAR 'P2' x'P2' slask
COPY/KD pix x'P2' npix/i/1/1
WRITE/OUT x'P2' created

==== SUB5.prg =====
COPY/IT 'P2' slask
ASSIGN/PRINT FILE a'P2'
PRINT/TABLE slask
WRITE/OUT a'P2' created

==== COPY.prg =====
COPY/II 'P2' x'P2'
WRITE/OUT x'P2' created